|
| 1 | +# MODULE: DownloadProject |
| 2 | +# |
| 3 | +# PROVIDES: |
| 4 | +# download_project( PROJ projectName |
| 5 | +# [PREFIX prefixDir] |
| 6 | +# [DOWNLOAD_DIR downloadDir] |
| 7 | +# [SOURCE_DIR srcDir] |
| 8 | +# [BINARY_DIR binDir] |
| 9 | +# [QUIET] |
| 10 | +# ... |
| 11 | +# ) |
| 12 | +# |
| 13 | +# Provides the ability to download and unpack a tarball, zip file, git repository, |
| 14 | +# etc. at configure time (i.e. when the cmake command is run). How the downloaded |
| 15 | +# and unpacked contents are used is up to the caller, but the motivating case is |
| 16 | +# to download source code which can then be included directly in the build with |
| 17 | +# add_subdirectory() after the call to download_project(). Source and build |
| 18 | +# directories are set up with this in mind. |
| 19 | +# |
| 20 | +# The PROJ argument is required. The projectName value will be used to construct |
| 21 | +# the following variables upon exit (obviously replace projectName with its actual |
| 22 | +# value): |
| 23 | +# |
| 24 | +# projectName_SOURCE_DIR |
| 25 | +# projectName_BINARY_DIR |
| 26 | +# |
| 27 | +# The SOURCE_DIR and BINARY_DIR arguments are optional and would not typically |
| 28 | +# need to be provided. They can be specified if you want the downloaded source |
| 29 | +# and build directories to be located in a specific place. The contents of |
| 30 | +# projectName_SOURCE_DIR and projectName_BINARY_DIR will be populated with the |
| 31 | +# locations used whether you provide SOURCE_DIR/BINARY_DIR or not. |
| 32 | +# |
| 33 | +# The DOWNLOAD_DIR argument does not normally need to be set. It controls the |
| 34 | +# location of the temporary CMake build used to perform the download. |
| 35 | +# |
| 36 | +# The PREFIX argument can be provided to change the base location of the default |
| 37 | +# values of DOWNLOAD_DIR, SOURCE_DIR and BINARY_DIR. If all of those three arguments |
| 38 | +# are provided, then PREFIX will have no effect. The default value for PREFIX is |
| 39 | +# CMAKE_BINARY_DIR. |
| 40 | +# |
| 41 | +# The QUIET option can be given if you do not want to show the output associated |
| 42 | +# with downloading the specified project. |
| 43 | +# |
| 44 | +# In addition to the above, any other options are passed through unmodified to |
| 45 | +# ExternalProject_Add() to perform the actual download, patch and update steps. |
| 46 | +# The following ExternalProject_Add() options are explicitly prohibited (they |
| 47 | +# are reserved for use by the download_project() command): |
| 48 | +# |
| 49 | +# CONFIGURE_COMMAND |
| 50 | +# BUILD_COMMAND |
| 51 | +# INSTALL_COMMAND |
| 52 | +# TEST_COMMAND |
| 53 | +# |
| 54 | +# Only those ExternalProject_Add() arguments which relate to downloading, patching |
| 55 | +# and updating of the project sources are intended to be used. Also note that at |
| 56 | +# least one set of download-related arguments are required. |
| 57 | +# |
| 58 | +# If using CMake 3.2 or later, the UPDATE_DISCONNECTED option can be used to |
| 59 | +# prevent a check at the remote end for changes every time CMake is run |
| 60 | +# after the first successful download. See the documentation of the ExternalProject |
| 61 | +# module for more information. It is likely you will want to use this option if it |
| 62 | +# is available to you. Note, however, that the ExternalProject implementation contains |
| 63 | +# bugs which result in incorrect handling of the UPDATE_DISCONNECTED option when |
| 64 | +# using the URL download method or when specifying a SOURCE_DIR with no download |
| 65 | +# method. Fixes for these have been created, the last of which is scheduled for |
| 66 | +# inclusion in CMake 3.8.0. Details can be found here: |
| 67 | +# |
| 68 | +# https://gitlab.kitware.com/cmake/cmake/commit/bdca68388bd57f8302d3c1d83d691034b7ffa70c |
| 69 | +# https://gitlab.kitware.com/cmake/cmake/issues/16428 |
| 70 | +# |
| 71 | +# If you experience build errors related to the update step, consider avoiding |
| 72 | +# the use of UPDATE_DISCONNECTED. |
| 73 | +# |
| 74 | +# EXAMPLE USAGE: |
| 75 | +# |
| 76 | +# include(download_project.cmake) |
| 77 | +# download_project(PROJ googletest |
| 78 | +# GIT_REPOSITORY https://github.com/google/googletest.git |
| 79 | +# GIT_TAG master |
| 80 | +# UPDATE_DISCONNECTED 1 |
| 81 | +# QUIET |
| 82 | +# ) |
| 83 | +# |
| 84 | +# add_subdirectory(${googletest_SOURCE_DIR} ${googletest_BINARY_DIR}) |
| 85 | +# |
| 86 | +#======================================================================================== |
| 87 | + |
| 88 | + |
| 89 | +set(_DownloadProjectDir "${CMAKE_CURRENT_LIST_DIR}") |
| 90 | + |
| 91 | +include(CMakeParseArguments) |
| 92 | + |
| 93 | +function(download_project) |
| 94 | + |
| 95 | + set(options QUIET) |
| 96 | + set(oneValueArgs |
| 97 | + PROJ |
| 98 | + PREFIX |
| 99 | + DOWNLOAD_DIR |
| 100 | + SOURCE_DIR |
| 101 | + BINARY_DIR |
| 102 | + # Prevent the following from being passed through |
| 103 | + CONFIGURE_COMMAND |
| 104 | + BUILD_COMMAND |
| 105 | + INSTALL_COMMAND |
| 106 | + TEST_COMMAND |
| 107 | + ) |
| 108 | + set(multiValueArgs "") |
| 109 | + |
| 110 | + cmake_parse_arguments(DL_ARGS "${options}" "${oneValueArgs}" "${multiValueArgs}" ${ARGN}) |
| 111 | + |
| 112 | + # Hide output if requested |
| 113 | + if (DL_ARGS_QUIET) |
| 114 | + set(OUTPUT_QUIET "OUTPUT_QUIET") |
| 115 | + else() |
| 116 | + unset(OUTPUT_QUIET) |
| 117 | + message(STATUS "Downloading/updating ${DL_ARGS_PROJ}") |
| 118 | + endif() |
| 119 | + |
| 120 | + # Set up where we will put our temporary CMakeLists.txt file and also |
| 121 | + # the base point below which the default source and binary dirs will be |
| 122 | + if (NOT DL_ARGS_PREFIX) |
| 123 | + set(DL_ARGS_PREFIX "${CMAKE_BINARY_DIR}") |
| 124 | + endif() |
| 125 | + if (NOT DL_ARGS_DOWNLOAD_DIR) |
| 126 | + set(DL_ARGS_DOWNLOAD_DIR "${DL_ARGS_PREFIX}/${DL_ARGS_PROJ}-download") |
| 127 | + endif() |
| 128 | + |
| 129 | + # Ensure the caller can know where to find the source and build directories |
| 130 | + if (NOT DL_ARGS_SOURCE_DIR) |
| 131 | + set(DL_ARGS_SOURCE_DIR "${DL_ARGS_PREFIX}/${DL_ARGS_PROJ}-src") |
| 132 | + endif() |
| 133 | + if (NOT DL_ARGS_BINARY_DIR) |
| 134 | + set(DL_ARGS_BINARY_DIR "${DL_ARGS_PREFIX}/${DL_ARGS_PROJ}-build") |
| 135 | + endif() |
| 136 | + set(${DL_ARGS_PROJ}_SOURCE_DIR "${DL_ARGS_SOURCE_DIR}" PARENT_SCOPE) |
| 137 | + set(${DL_ARGS_PROJ}_BINARY_DIR "${DL_ARGS_BINARY_DIR}" PARENT_SCOPE) |
| 138 | + |
| 139 | + # Create and build a separate CMake project to carry out the download. |
| 140 | + # If we've already previously done these steps, they will not cause |
| 141 | + # anything to be updated, so extra rebuilds of the project won't occur. |
| 142 | + configure_file("${_DownloadProjectDir}/DownloadProject.CMakeLists.cmake.in" |
| 143 | + "${DL_ARGS_DOWNLOAD_DIR}/CMakeLists.txt") |
| 144 | + execute_process(COMMAND ${CMAKE_COMMAND} -G "${CMAKE_GENERATOR}" . |
| 145 | + RESULT_VARIABLE result |
| 146 | + ${OUTPUT_QUIET} |
| 147 | + WORKING_DIRECTORY "${DL_ARGS_DOWNLOAD_DIR}" |
| 148 | + ) |
| 149 | + if(result) |
| 150 | + message(FATAL_ERROR "CMake step for ${DL_ARGS_PROJ} failed: ${result}") |
| 151 | + endif() |
| 152 | + execute_process(COMMAND ${CMAKE_COMMAND} --build . |
| 153 | + RESULT_VARIABLE result |
| 154 | + ${OUTPUT_QUIET} |
| 155 | + WORKING_DIRECTORY "${DL_ARGS_DOWNLOAD_DIR}" |
| 156 | + ) |
| 157 | + if(result) |
| 158 | + message(FATAL_ERROR "Build step for ${DL_ARGS_PROJ} failed: ${result}") |
| 159 | + endif() |
| 160 | + |
| 161 | +endfunction() |
0 commit comments