test: add failing test for distributionManagement.relocation.

Author: autonomousapps

src/functionalTest/groovy/com/autonomousapps/jvm/PomRelocationSpec.groovy

@@ -0,0 +1,32 @@
+package com.autonomousapps.jvm
+
+import com.autonomousapps.jvm.projects.PomRelocationProject
+import spock.lang.PendingFeature
+
+import static com.autonomousapps.utils.Runner.build
+import static com.google.common.truth.Truth.assertThat
+
+/**
+ * See also discussion in {@link com.autonomousapps.transform.StandardTransform#computeAdvice} function. There we
+ * deliberately strip possible advice to declare {@code runtimeOnly} dependencies that are in the transitive graph.
+ * Doing that would likely be disruptive, so a more targeted approach is to try to find some direct way of supporting
+ * {@code relocation}s in a .pom file.
+ */
+final class PomRelocationSpec extends AbstractJvmSpec {
+
+  @PendingFeature(reason = "Gradle transparently processes the relocation, offering no way for end users to know that it's happened")
+  def "handles POM distributionManagement.relocation (#gradleVersion)"() {
+    given:
+    def project = new PomRelocationProject()
+    gradleProject = project.gradleProject
+
+    when:
+    build(gradleVersion, gradleProject.rootDir, 'buildHealth', ':proj:reason', '--id', 'com.mysql:mysql-connector-j')
+
+    then:
+    assertThat(project.actualProjectAdvice()).containsExactlyElementsIn(project.expectedProjectAdvice)
+
+    where:
+    gradleVersion << gradleVersions()
+  }
+}

src/functionalTest/groovy/com/autonomousapps/jvm/projects/PomRelocationProject.groovy

@@ -0,0 +1,63 @@
+package com.autonomousapps.jvm.projects
+
+import com.autonomousapps.AbstractProject
+import com.autonomousapps.kit.GradleProject
+import com.autonomousapps.model.Advice
+import com.autonomousapps.model.ProjectAdvice
+
+import static com.autonomousapps.AdviceHelper.*
+import static com.autonomousapps.kit.gradle.Dependency.implementation
+import static com.autonomousapps.kit.gradle.Dependency.runtimeOnly
+
+final class PomRelocationProject extends AbstractProject {
+
+  /*
+   * `mysql:mysql-connector-java` pom file:
+   *
+   *  <groupId>mysql</groupId>
+   *  <artifactId>mysql-connector-java</artifactId>
+   *  <version>8.0.33</version>
+   *  <distributionManagement>
+   *    <relocation>
+   *      <groupId>com.mysql</groupId>
+   *      <artifactId>mysql-connector-j</artifactId>
+   *      <message>MySQL Connector/J artifacts moved to reverse-DNS compliant Maven 2+ coordinates.</message>
+   *    </relocation>
+   *  </distributionManagement>
+   */
+
+  // This is a shim that redirects to `com.mysql:mysql-connector-j:8.0.33` via `distributionManagement.relocation`.
+  // Also, this should be runtimeOnly since it's not used at compile- time.
+  private final mySqlShim = implementation('mysql:mysql-connector-java:8.0.33')
+  private final mySql = runtimeOnly('com.mysql:mysql-connector-j:8.0.33')
+
+  final GradleProject gradleProject
+
+  PomRelocationProject() {
+    this.gradleProject = build()
+  }
+
+  private GradleProject build() {
+    return newGradleProjectBuilder()
+      .withSubproject('proj') { c ->
+        c.withBuildScript { bs ->
+          bs.plugins = javaLibrary
+          bs.dependencies(mySqlShim)
+        }
+      }
+      .write()
+  }
+
+  private final Set<Advice> projAdvice = [
+    Advice.ofRemove(moduleCoordinates(mySqlShim), 'implementation'),
+    Advice.ofAdd(moduleCoordinates(mySql), 'runtimeOnly'),
+  ]
+
+  Set<ProjectAdvice> actualProjectAdvice() {
+    return actualProjectAdvice(gradleProject)
+  }
+
+  final Set<ProjectAdvice> expectedProjectAdvice = [
+    projectAdviceForDependencies(':proj', projAdvice),
+  ]
+}

src/main/kotlin/com/autonomousapps/tasks/ComputeUsagesTask.kt

@@ -316,6 +316,8 @@ private class GraphVisitor(
   private fun noRealCapabilities(dependency: Dependency): Boolean {
     if (dependency.capabilities.isEmpty()) return true
 
+    // TODO(tsr): this doesn't match the kdoc. Is this wrong or is the kdoc wrong? I think this is wrong, but no tests
+    //  are failing...
     val single = dependency.capabilities.values.singleOrNull { it is InferredCapability || it is NativeLibCapability }
 
     return (single as? InferredCapability)?.isCompileOnlyAnnotations == false

src/main/kotlin/com/autonomousapps/transform/StandardTransform.kt

@@ -243,6 +243,10 @@ internal class StandardTransform(
       // Don't add unused usages!
       .filterUsed()
       // Don't add runtimeOnly or compileOnly (compileOnly, compileOnlyApi, providedCompile) declarations
+      // nb: this probably remains the correct choice, but it can lead to issues when we remove an "unused" dependency
+      // and fail to add a required runtimeOnly dependency that was part of the unused dep's transitive graph. Removing
+      // this line would lead to "super strict" declarations that are, perhaps, more bazel-like (every classpath
+      // consists only of positively-declared dependencies).
       .filterNot { it.bucket == Bucket.RUNTIME_ONLY || it.bucket == Bucket.COMPILE_ONLY }
       .mapTo(advice) { usage ->
         val preferredCoordinatesNotation =