main.tf

locals {
  instance_name = strcontains(var.deployment_id, "postgresql") ? var.deployment_id : "${var.deployment_id}-postgresql"
  network_id    = "projects/${var.project_id}/global/networks/${var.network}"
}

resource "google_sql_database_instance" "instance" {
  name             = local.instance_name
  project          = var.project_id
  region           = var.region
  database_version = "POSTGRES_${var.postgres_version}"
  root_password    = random_password.postgres_password.result

  settings {
    tier = "db-custom-${var.cpu_count}-${var.ram_mb}"
    edition = var.use_enterprise_plus ? "ENTERPRISE_PLUS" : "ENTERPRISE"
    availability_type = "REGIONAL"

    user_labels = {
      deployment_id = var.deployment_id
    }

    deletion_protection_enabled = var.deletion_protection

    data_cache_config {
      data_cache_enabled = var.use_enterprise_plus
    }

    backup_configuration {
      enabled = var.backup_enabled
      point_in_time_recovery_enabled = var.backup_enabled
    }

    ip_configuration {
      ipv4_enabled                                  = false
      private_network = local.network_id
      enable_private_path_for_google_cloud_services = true
    }

    database_flags {
      name  = "cloudsql.iam_authentication"
      value = "on"
    }
  }

  deletion_protection = var.deletion_protection
}

resource "random_password" "postgres_password" {
  length = 16
}