build.gradle

buildscript {
    ext.kotlin_version = '1.2.41'
    ext.retrofit_version = '2.3.0'

    repositories {
        jcenter()
    }
    dependencies {
        classpath "org.jetbrains.kotlin:kotlin-gradle-plugin:$kotlin_version"
    }
}

apply plugin: 'kotlin'

repositories {
    jcenter()
}

configurations {
    ktlint
}

dependencies {
    ktlint "com.github.shyiko:ktlint:0.23.1"

    implementation "org.jetbrains.kotlin:kotlin-stdlib:$kotlin_version"
    compileOnly "com.squareup.retrofit2:retrofit:$retrofit_version"

    testImplementation 'junit:junit:4.12'
    testImplementation 'com.squareup.okhttp3:mockwebserver:3.8.0'
    testImplementation "com.squareup.retrofit2:converter-gson:$retrofit_version"
    testImplementation 'net.jodah:concurrentunit:0.4.3'
}

task ktlint(type: JavaExec, group: "verification") {
    description = "Check Kotlin code style."
    classpath = configurations.ktlint
    main = "com.github.shyiko.ktlint.Main"
    args "src/**/*.kt"
}
check.dependsOn ktlint

task ktlintFormat(type: JavaExec, group: "formatting") {
    description = "Fix Kotlin code style deviations."
    classpath = configurations.ktlint
    main = "com.github.shyiko.ktlint.Main"
    args "-F", "src/**/*.kt"
}

task wrapper(type: Wrapper) {
    description 'Creates the gradle wrapper.'
    gradleVersion '4.6'
    distributionUrl = distributionUrl.replace("bin", "all")
}