Configure publishing

gradle.properties

@@ -1,2 +1,3 @@
-org.gradle.parallel=true
-org.gradle.caching=true
+org.gradle.configuration-cache=true
+group=io.github.rieske.postgres-cdc
+version=0.0.1

gradle/build-logic/build.gradle

@@ -0,0 +1,3 @@
+plugins {
+    id("groovy-gradle-plugin")
+}

gradle/build-logic/settings.gradle

@@ -0,0 +1 @@
+rootProject.name = "build-logic"

gradle/build-logic/src/main/groovy/io.github.rieske.postgres-cdc.java-library.gradle

@@ -0,0 +1,22 @@
+plugins {
+    id("java-library")
+}
+
+java {
+    sourceCompatibility = JavaVersion.VERSION_11
+    withSourcesJar()
+    withJavadocJar()
+}
+
+testing {
+    suites {
+        test {
+            useJUnitJupiter()
+        }
+    }
+}
+
+tasks.withType(Javadoc).configureEach {
+    // TODO: figure the public API and document it!
+    //options.addStringOption("Xwerror", "-quiet")
+}

gradle/build-logic/src/main/groovy/io.github.rieske.postgres-cdc.published-library.gradle

@@ -0,0 +1,52 @@
+plugins {
+    id("io.github.rieske.postgres-cdc.java-library")
+    id("maven-publish")
+    id("signing")
+}
+
+publishing {
+    publications {
+        maven(MavenPublication) {
+            from(components.java)
+            project.afterEvaluate {
+                pom {
+                    name = "${group}:${project.name}"
+                    description = "${project.description}"
+                    url = "https://github.com/rieske/postgres-cdc"
+                    licenses {
+                        license {
+                            name = "The Apache License, Version 2.0"
+                            url = "https://www.apache.org/licenses/LICENSE-2.0.txt"
+                        }
+                    }
+                    developers {
+                        developer {
+                            id = "rieske"
+                            name = "Vaidotas Valuckas"
+                            email = "vaidotas.valuckas@gmail.com"
+                        }
+                    }
+                    scm {
+                        connection = "scm:git:git@github.com/rieske/postgres-cdc.git"
+                        developerConnection = "scm:git:ssh@github.com:rieske/postgres-cdc.git"
+                        url = "https://github.com/rieske/postgres-cdc"
+                    }
+                }
+            }
+        }
+    }
+    repositories {
+        maven {
+            url = uri("https://s01.oss.sonatype.org/service/local/staging/deploy/maven2")
+            credentials(PasswordCredentials)
+        }
+    }
+}
+
+signing {
+    def signingKey = findProperty("signingKey")
+    def signingPassword = findProperty("signingPassword")
+    useInMemoryPgpKeys(signingKey, signingPassword)
+    sign(publishing.publications.maven)
+}
+

lib/build.gradle

@@ -1,9 +1,5 @@
 plugins {
-    id("java-library")
-}
-
-java {
-    sourceCompatibility = JavaVersion.VERSION_11
+    id("io.github.rieske.postgres-cdc.published-library")
 }
 
 dependencies {
@@ -18,7 +14,6 @@ dependencies {
 testing {
     suites {
         test {
-            useJUnitJupiter()
             dependencies {
                 implementation("org.testcontainers:postgresql:1.19.1")
                 implementation("org.assertj:assertj-core:3.24.2")

settings.gradle

@@ -1,3 +1,6 @@
+pluginManagement {
+    includeBuild("gradle/build-logic")
+}
 dependencyResolutionManagement {
     repositories {
         mavenCentral()